CrossTab.aspx Page

Description:   The CrossTab.aspx page shows a quarterly breakdown of sales based on geographical region. It also displays the totals for each region, the totals for each month within the quarter, and the total for the whole quarter.

Overview:   The CrossTab Report shows totals for each region in the footer of the Datagrid. The totals for each month of the quarter are shown in the rightmost column. The grand total for the quarter is calculated and displayed in the bottom right corner.

This report uses the same technique of grouping related data that is used in the Tabular report (in this case, grouping sales data by quarter). The grouping is done by nesting a DataGrid control inside of a DataList control.

Since the data is time-based, to provide better performance the reports are filtered by year.

Implementation Notes:    As the Datagrids for each quarter are being databound, the running totals are summed.

    '*********************************************************************
    '
    ' The SumItems event handler is for the OnItemDataBound event of the datagrids for each quarter.
    ' It adds running totals for each region for a particular quarter.
    ' It also adds the sum totals fo the regions of the quarter as well.
    '
    '*********************************************************************

    Protected Sub SumItems(ByVal sender As Object, ByVal e As System.Web.UI.WebControls.DataGridItemEventArgs)
        ' sum up the data in the columns as the datagrid is databinding
        If e.Item.ItemType = ListItemType.Item Or e.Item.ItemType = ListItemType.AlternatingItem Then
            ' get the sales value for eastern region
            Dim eastern As Double = Convert.ToDouble(e.Item.Cells(1).Text)
            ' add sales value to the running total
            _eastern += eastern
            ' format to display sales value as currency
            e.Item.Cells(1).Text = String.Format("{0:c}", eastern)

            Dim western As Double = Convert.ToDouble(e.Item.Cells(2).Text)
            _western += western
            e.Item.Cells(2).Text = String.Format("{0:c}", western)

            Dim southern As Double = Convert.ToDouble(e.Item.Cells(3).Text)
            _southern += southern
            e.Item.Cells(3).Text = String.Format("{0:c}", southern)

            Dim northern As Double = Convert.ToDouble(e.Item.Cells(4).Text)
            _northern += northern
            e.Item.Cells(4).Text = String.Format("{0:c}", northern)

            Dim totals As Double = Convert.ToDouble(e.Item.Cells(5).Text)
            _totals += totals
            e.Item.Cells(5).Text = String.Format("{0:c}", totals)
        Else
            If e.Item.ItemType = ListItemType.Footer Then
                ' display our summations in footer
                e.Item.Cells(0).Text = "Totals"
                e.Item.Cells(0).HorizontalAlign = HorizontalAlign.Left
                e.Item.Cells(1).Text = String.Format("{0:c}", _eastern)
                e.Item.Cells(2).Text = String.Format("{0:c}", _western)
                e.Item.Cells(3).Text = String.Format("{0:c}", _southern)
                e.Item.Cells(4).Text = String.Format("{0:c}", _northern)
                e.Item.Cells(5).Text = String.Format("{0:c}", _totals)

                ' reset the running totals for next datagrid
                _eastern = 0
                _western = 0
                _southern = 0
                _northern = 0
                _totals = 0
            End If
        End If
    End Sub 'SumItems
		

To group the related data, a DataGrid control is nested inside of a DataList control. The DataGrid control is used here since it is more flexible to format the look and feel of it.

The filter by year is done by calling the GetRegionSales method with the selected year filter.

    Protected Function GetQuarterDetails(ByVal quarter As Integer) As CrossTabReportCollection
        Return CrossTabReport.GetRegionSales(quarter, Convert.ToInt32(YearDropDownList.SelectedItem.Value))
    End Function 'GetQuarterDetails